Hi guys,

I have this mc in my movie, and I want the volume of a certain sound to increase/fade up as the cursor gets closer to the mc, and also want it to decrease/fade down as the cursor gets away from the mc.

I've got this code:

onClipEvent (load) {
	s_jam = new Sound(this);
	s_jam.attachSound("jam");
	s_jam.start(0, 999);
	s_jam.setVolume(0);
	startVol = 100;
}
onClipEvent (enterFrame) {
	xSide = _root._xmouse-this._x;
	ySide = _root._ymouse-this._y;
	hypo = Math.sqrt((xSide*xSide)+(ySide*ySide));
	if (hypo<100) {
		if (jamStopped == true) {
			s_jam.start(0, 999);
			jamStopped = false;
		}
		deltaV = startVol-(startVol*(hypo*.01));
	} else {
		deltaV = 0;
		s_jam.stop();
		jamStopped = true;
	}
	s_jam.setVolume(deltaV);
}

But it seems pretty archaic, since I think it was done for flash 5, and also I want to be able to customize the distance at which the sound starts to fade.

Does anybody know someway of doing it, or how to fix this code?

[Nutrox]

function getVolume( target:MovieClip, maxDistance:Number ):Number {
    var vol:Number = 100 - ((getDistance(target)/maxDistance) * 100 >> 0);
    if (vol < 0) {
        vol = 0;
    }
    return vol;
}
 
function getDistance( target:MovieClip ):Number {
    var pos:Object = getGlobalPosition(target);
    var mX:Number = _root._xmouse - (target._width / 2);
    var mY:Number = _root._ymouse - (target._height / 2);
    var x:Number = mX - pos.x;
    var y:Number = mY - pos.y;
    return Math.sqrt((x * x) + (y * y));
}
 
function getGlobalPosition( target:MovieClip ):Object {
    var x:Number = target._x;
    var y:Number = target._y;
    var mc:MovieClip = target._parent;
    while (mc) {
        x += mc._x;
        y += mc._y;
        mc = mc._parent;
    }
    return {x:x, y:y};
} 

To get the volume you would do something like this:

var volume:Number = getVolume(_root.myMovieClip, 100);
mySound.setVolume(volume); 

getVolume( targetMovieClip, maxDistance )

maxDistance is the distance where the volume will be zero. So, if you want the volume to be zero if the mouse is futher than 50px away from the movie clip, then you would pass 50 as the maxDistance value.

Hope that helps.

[kindoki]

Sorry, I'm pretty lame at actionscript.

Is that code supposed to be inserted in the timeline? And after this?

this.onLoad = function () {
	s_jam = new Sound(this);
	s_jam.attachSound("jam");
	s_jam.start(0, 999);
	s_jam.setVolume(0);
	startVol = 100;
}

And what about this piece of code?

var volume:Number = getVolume(_root.myMovieClip, 100);
mySound.setVolume(volume);

Is that to use also in the timeline after all the other code?

And:

getVolume( targetMovieClip, maxDistance )

That's when I want to call the function right?
So if my mc is called "ball", and if I want the sound to go off at 250 pix, it should be:

getVolume( ball, 250 )

Right?

There is also something wrong with the code cause Flash pops up this message:

**Error** Scene=Scene 1, layer=jammed full, frame=1:Line 1: '{' expected
function getVolume( target:MovieClip, maxDistance:Number ):Number {

**Error** Scene=Scene 1, layer=jammed full, frame=1:Line 7: Unexpected '}' encountered
}

Total ActionScript Errors: 2 Reported Errors: 2

Sorry for being so lame. And thank you for your help.

[Nutrox]

You can just put that code into the first frame of your movie ( i.e. the main time line ).

When you want to update the volume of a sound you simply call the getVolume function, so you could use onEnterFrame:

this.onEnterFrame = function():Void {
   var newVolume = _root.getVolume(ball, 250);
   s_jam.setVolume(newVolume);
} 

I think you are getting the error because this code is AS2, so make sure that you have your publish settings set to ActionScript 2.0

[kindoki]

It works!



I created a new .fla and if I use this code in the first frame of the main timeline of scene 1, it works. But if I use the code in the second frame in the same timeline it no longer works. Is it really necessary to use the code on the first frame of the main timeline? I'm asking this because I want to use this in my project, this code is supposed to be used on the second frame of a movie clip inside another movie clip on the main timeline, and it doesn't work. Is there anyway to solve this issue?

Thank you very much for your help



EDITh I'm using attachSound BTW, is that what's causing the problem?