Hi guys i did search this to get my answer but still now joy.

function logout() {
    trace("holderc:"+holderc.numChildren);
    var i:Number=holderc.numChildren;
    while (i--) {
        holderc.removeChildAt(i);
        trace("holder i:"+i)
    }
} 

It only removes one child from the stage and not all of them.
Anyone got any idea what i am doing wrong?

thanks

[spooky]

Use "try/catch" on parts of your script that executes before the "logout" function.

Might be some silent error happening somewhere, preventing your script from finishing.

[sims11tz]

hmmm what does holderc.numChildren trace out as? maybe try var i:Number=holderc.numChildren-1;

[--DJD--]

Sorry bud try/catch? I only started with AS3 yesterday but i have been doign AS2 for years. Can you explain how i could use try/catch.

This is really bugging me. it the last piece of the puzzle in completing my first AS3 project.

Thanks for any helps

[--DJD--]

Quote: Originally Posted by sims11tz

hmmm what does holderc.numChildren trace out as? maybe try var i:Number=holderc.numChildren-1;

trace's
5
4
3
2
1
0

[--DJD--]

ok this is wierd
I tried

i:Number=holderc.numChildren-1; 

This removed 6 objects from inside the mc attached and not the attached mc it's self.
Worse still 3 of these objects are just drawn vecotrs.

[spooky]

This may help you keep from removing the DisplayObjects you intend to keep.
Here this will only remove Sprites.

if(holderc.getChildAt(i) && holderc.getChildAt(i) is Sprite){				
	holderc.removeChildAt(i);				
}

[--DJD--]

Quote: Originally Posted by spooky

This may help you keep from removing the DisplayObjects you intend to keep.
Here this will only remove Sprites.

if(holderc.getChildAt(i) && holderc.getChildAt(i) is Sprite){				
	holderc.removeChildAt(i);				
}

I did try is Sprite and it did nothing and i changed it to displayObject and it did the same thing again and removed objects from within the mc i am trying to remove rather than the mc it's self.

[spooky]

Quote: Originally Posted by -[DJD]-

I did try is Sprite and it did nothing and i changed it to displayObject and it did the same thing again and removed objects from within the mc i am trying to remove rather than the mc it's self.

Not sure what you intend but, If you want to remove "holderc":
holderc.parent.removeChild(holderc);

[--DJD--]

This is how i am attaching mc's from the libarary ontot the stage.

var nextcY:Number = 466;
var counCount:Number = data_lv.countryCount;
var holderc:MovieClip;
for (var countC:Number=0; countC<counCount; countC++) {
    holderc = makeListCountry();
    addChild(holderc);
    holderc.x=12;
    holderc.y = nextcY;
    holderc.txCountry.text = data_lv['country'+countC+'country'];
    holderc.txPerc.text = data_lv['country'+countC+'countryPercent']+" %";
    holderc.txCount.text = data_lv['country'+countC+'countryCount'];
    holderc.mc.scaleX = Math.round(data_lv['country'+countC+'countryPercent'])/100;
    nextcY += 24;
}
 
function makeListCountry():MovieClip {
    var myObject:mcCountry = new mcCountry ();
    return myObject;
} 

So what i want to do is then remove the mc's that have just been attached.
For some reason my script removes objects from within the attached mc and not the mc it's self.

[sims11tz]

you are adding the children to your document classes display list.... so they must be removed from the same display list:

      function logout() {
          var i:Number=this.numChildren-1;
          while (i--) {
              removeChildAt(i);
          }
      }

[--DJD--]

Quote: Originally Posted by sims11tz

you are adding the children to your document classes display list.... so they must be removed from the same display list:

      function logout() {
          var i:Number=this.numChildren-1;
          while (i--) {
              removeChildAt(i);
          }
      }

That just totally wiped my stage clear of everything.

[sims11tz]

doh, thats what I thought you were going for. I am officially now lost at what you are trying to accomplish. So you just want to remove all of the holderc that are added to the stage? If so you can push them into an array after you instantiate them from the library. Than loop through that array and remove all items in it.... ? If that isn't it.. what exactly are you going for?

[wraevn]

Try this when adding to the stage:

for (var countC:Number=0; countC < counCount; countC++) {
    holderc=makeListCountry();
             holderc.name = "holderc_" + countC;
    addChild(holderc);
    holderc.x=12;
    holderc.y=nextcY;
    holderc.txCountry.text=data_lv['country' + countC + 'country'];
    holderc.txPerc.text=data_lv['country' + countC + 'countryPercent'] + " %";
    holderc.txCount.text=data_lv['country' + countC + 'countryCount'];
    holderc.mc.scaleX=Math.round(data_lv['country' + countC + 'countryPercent']) / 100;
    nextcY+= 24;
} 

(added name)

Then for your removal script:

function logout() {
    var i:Number=this.numChildren-1;
    while (i--) {
        if(getChildAt(i).name.indexOf("holderc_") == 0){
            removeChildAt(i);
        }
    }
} 

[--DJD--]

wraevn i owe you a pint Let me know when your in Glasgow
ok so since discovered that my mc's are being attahced directly onto the stage.
My normal method is to create an empty movie clip then attache my mc's to that. Is there a similar method for doing this in AS3?

[wraevn]

Sure -

var emptyMC:MovieClip= new MovieClip();
emptyMC.name = "emptyMC";
//could also use var emptyS:Sprite = new Sprite();
addChild(emptyMC);
 
for (var countC:Number=0; countC < counCount; countC++) {
    var myObject:mcCountry = new mcCountry();
    emptyMC.addChild(myObject);
    myObject.x=12;
    myObject.y=nextcY;
    myObject.txCountry.text=data_lv['country' + countC + 'country'];
    myObject.txPerc.text=data_lv['country' + countC + 'countryPercent'] + " %";
    myObject.txCount.text=data_lv['country' + countC + 'countryCount'];
    myObject.mc.scaleX=Math.round(data_lv['country' + countC + 'countryPercent']) / 100;
    nextcY+= 24;
}
 
//then to remove
 
function logout():void{
    removeChild(getChildByName("emptyMC"));
} 

[buzcajun]

wraevn,

I know this is an old post, but I thought I would try it anyway. I am having some issues, removingChildren. I am doing simple load to stage an external SWF, and when I try to load another, in the same tagetMC, the other is still there and when you go back its just adds until the memory is toast.

I tried addChildAt(), I tried naming the loader, nothing seems to work.