I have a movieclip button on the main stage with an instance name of X. Essentially I just need to pass this instance name from the button to a function. At the moment I have:

Button code:

	var X = _root.X.onPress = Delegate.create (this, buttonClick);
		X.button = "X";

Button function:

	function buttonClick ()
		{
		textBox.text = arguments.caller.button;
		}

This works but as I have lots of buttons like this I have to create loads of vars, which is slowing down my movie. Does anyone know if there is another way?

Thanks!

[-Loren-]

You can try using

MovieClip._name 

so,

function buttonClick ()
{
    textBox.text = arguments.caller._name;
} 

You might need to try this, not sure:

function buttonClick ()
{
    textBox.text = MovieClip(arguments.caller)._name;
} 

Let me know if this works for you

[bob_300]

Thanks, I tried that but no joy. It traces undefined;

If trace(this); within button click I get an response of [object Object]. Could the name be within this object?

[-Loren-]

You could definitely try that, but it shouldn't work since you're Delegating that function call. Try it I suppose

[Nutrox]

arguments.caller is a reference to the function that called the executing function, it won't be a reference to the object that called the executing function:

function a():Void
{
    b();
}
 
function b():Void
{
    trace( arguments.caller == a ); // true
}
 
a(); 

I use a custom Delegate class because it allows you to pass custom arguments to a function without overwriting any of the default arguments that may be passed to the function by Flash. So, you could do something like this:

import neondust.utils.Delegate;
 
someButton.onRelease = Delegate.create( this, buttonClick, someButton );
 
function buttonClick( target:MovieClip ):Void
{
    trace( this ); // _level0
    trace( target == someButton ); // true
    trace( target._name ); // someButton
} 

Here is the class:

class neondust.utils.Delegate
{
    public static function create( scope:Object, func:Function ):Function
    {
        var args:Array = arguments.splice( 2 );
        return function()
        {
            return func.apply( scope, args.concat( arguments ) );
        }
    }
} 

Your custom arguments will precede any of the default arguments sent to the function by Flash, if any.

[bob_300]

Hey thanks, thats great it works a treat!

It is a lot easier this way, but is it also better performance wise?

[Nutrox]

Having lots of variables shouldn't slow down the movie really, the main cause of slowdown would be the graphics. If your movie is running slow then the graphics are the first thing you should try to optimise.