Ultrashock Forums > Flash > ActionScript
• [mini-tutorial] Center MovieClip on Stage

You are currently viewing our website as a guest which gives you limited access to forums, files and other resources.

Click here to join now for free, and start interacting with our members, download files and much more!

Click here if you are looking for our Flash files and other professional assets.
  
Post Reply | View first unread | Rating: Thread Rating: 4 votes, 4.75 average. Search this Thread | Thread Tools | Display Modes
1|2|> Page 1 of 2

#1
Bookmark and Share!
[mini-tutorial] Center MovieClip on Stage
Old 2004-12-14

Tonight for a project I sat down to figure out how to center a movieclip with 100% height and width (with noScale) on the stage, and after quickly working up a demonstration I thought I would put the AS and FLA up due to the lack of information that I found when I was trying to create it.

CenterStage Demo
Here's the AS being used, it should be well documented:
ActionScript Code:
  1. /*
  2. Created by Jonathan Moore - NewEzra.com
  3. Feel free to use this how ever you want commercial/non-commercial.
  4. Just don't take credit writing it ;)
  5. */
  6.  
  7. //Set stage to fill screen and align top left
  8. Stage.scaleMode = "noScale";
  9. Stage.align = "TL";
  10.  
  11. //Create text fieldS to display stage height/width
  12. this.createTextField("stageSize_txt", this.getNextHighestDepth(), 0, 0, 100, 20);
  13. stageSize_txt.background = true;
  14. stageSize_txt.backgroundColor = 0x333333;
  15. stageSize_txt.textColor = 0xFFFFFF;
  16.  
  17. this.createTextField("credits_txt", this.getNextHighestDepth(), 0, 0, 100, 20);
  18. credits_txt.background = true;
  19. credits_txt.backgroundColor = 0x333333;
  20. credits_txt.textColor = 0xFFFFFF;
  21.  
  22. //Creates centerBox to demonstrate centering a MC on the Stage
  23. this.createEmptyMovieClip("centerBox", this.getNextHighestDepth());
  24. centerBox.beginFill(0xFFFFFF);
  25. centerBox.moveTo(0, 0);
  26. centerBox.lineTo(50, 0);
  27. centerBox.lineTo(50, 35);
  28. centerBox.lineTo(0, 35);
  29. centerBox.lineTo(0, 0);
  30. centerBox.endFill();
  31.  
  32. //Function defines and sets based on initial Stage properties
  33. stageResize = function(){
  34.     stageSize_txt.text = "Stage Width:"+Stage.width+", Stage Height:"+Stage.height; 
  35.     stageSize_txt._width = Stage.width; 
  36.     centerBox._x = Math.round((Stage.width/2)-(centerBox._width/2));
  37.     centerBox._y = Math.round((Stage.height/2)-(centerBox._height/2));
  38.     credits_txt._width = Stage.width;
  39.     credits_txt._y = (Stage.height) - credits_txt._height;
  40.     credits_txt.text = "Created by: New Ezra - Box _x:"+centerBox._x+", Box _y:"+centerBox._y;
  41. }
  42. //All non-IE browsers need this in order to set initial properties
  43. //IE automaticly calls back onResize when opened
  44. //**Possible bug - submitted to Macromedia
  45. stageResize();
  46.  
  47. //Creates stageListener Object
  48. var stageListener:Object = new Object();
  49. //Defines function for stage onResize
  50. stageListener.onResize = function() {
  51.     stageResize();  
  52. };
  53. //Adds the stageListener to call 
  54. Stage.addListener(stageListener);

HTML used to embed the swf:
Code:
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
<title>New Ezra - Ultrashock Mini-Tutorial | centerStage</title>
<style type="text/css">
<!--
html, body {
     width: 100%;
     height: 100%;
     margin: 0px;
     padding: 0px;
}
-->
</style>
</head>
<body bgcolor="#ffffff">
<!--url's used in the movie-->
<!--text used in the movie-->
<object classid="clsid:d27cdb6e-ae6d-11cf-96b8-444553540000" codebase="http://fpdownload.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=7,0,0,0" width="100%" height="100%" id="centerStage">
  <param name="allowScriptAccess" value="sameDomain" />
  <param name="movie" value="centerStage.swf" />
  <param name="quality" value="high" />
  <param name="scale" value="noscale" />
  <param name="salign" value="tl" />
  <param name="bgcolor" value="#9EA9B1" />
  <embed src="centerStage.swf" quality="high" scale="noscale" bgcolor="#9EA9B1" width="100%" height="100%" name="centerStage" align="tl" allowscriptaccess="sameDomain" type="application/x-shockwave-flash" pluginspage="http://www.macromedia.com/go/getflashplayer" />
  </embed>
  </embed>
</object>
</body>
</html>
Download the FLA
Few people are capable of expressing with equanimity opinions which differ from the prejudices of their social environment. Most people are even incapable of forming such opinions. -- Albert Einstein.

www.newezra.com | www.2advanced.com
postbit arrow 41 comments | 10011 views postbit arrow Reply: with Quote   
Registered User
 NewEzra is offline
seperator
Posts: 3,580
2002-09-19
Age: 29
NewEzra lives in United States
 NewEzra's Avatar
seperator

Ultrashock Member Comments:
netweight netweight is offline netweight lives in Germany 2004-12-14 #2 Old  
Downloaded
Reply With Quote  
Brad-J Brad-J is offline Brad-J lives in United States 2004-12-15 #3 Old  
thanks bluebox! nice scripting there.
Reply With Quote  
Prem's Avatar Prem Prem is offline Prem lives in Sri Lanka 2004-12-15 #4 Old  
nice tut Bluebox
Reply With Quote  
B-Rhapsody's Avatar B-Rhapsody B-Rhapsody is offline B-Rhapsody lives in Philippines 2004-12-15 #5 Old  
that is so brilliant.
Reply With Quote  
Julian's Avatar Julian Julian is offline Julian lives in United States 2 Creative Assets 2004-12-15 #6 Old  
Good tutorial, very useful.

Downloaded...
Reply With Quote  
Flexbaby Flexbaby is offline 2004-12-15 #7 Old  
great tut bluebox
Reply With Quote  
feel feel is offline 2004-12-15 #8 Old  
how to add easing on the moiveclip move to center?
Reply With Quote  
Julian's Avatar Julian Julian is offline Julian lives in United States 2 Creative Assets 2004-12-15 #9 Old  
Feel:

ActionScript Code:
  1. /*
  2. Created by Jonathan Moore - NewEzra.com
  3. Feel free to use this how ever you want commercial/non-commercial.
  4. Just don't take credit writing it <img src="images/smilies/wink.gif" border="0" alt="">
  5. */
  6. //Set stage to fill screen and align top left
  7. Stage.scaleMode = "noScale";
  8. Stage.align = "TL";
  9. //Create text fieldS to display stage height/width
  10. this.createTextField("stageSize_txt", this.getNextHighestDepth(), 0, 0, 100, 20);
  11. stageSize_txt.background = true;
  12. stageSize_txt.backgroundColor = 0x333333;
  13. stageSize_txt.textColor = 0xFFFFFF;
  14. this.createTextField("credits_txt", this.getNextHighestDepth(), 0, 0, 100, 20);
  15. credits_txt.background = true;
  16. credits_txt.backgroundColor = 0x333333;
  17. credits_txt.textColor = 0xFFFFFF;
  18. //Creates centerBox to demonstrate centering a MC on the Stage
  19. this.createEmptyMovieClip("centerBox", this.getNextHighestDepth());
  20. centerBox.beginFill(0xFFFFFF);
  21. centerBox.moveTo(0, 0);
  22. centerBox.lineTo(50, 0);
  23. centerBox.lineTo(50, 35);
  24. centerBox.lineTo(0, 35);
  25. centerBox.lineTo(0, 0);
  26. centerBox.endFill();
  27. //Function defines and sets based on initial Stage properties
  28. stageResize = function () {
  29.     stageSize_txt.text = "Stage Width:"+Stage.width+", Stage Height:"+Stage.height;
  30.     stageSize_txt._width = Stage.width;
  31.     centerBox._x = Math.round((Stage.width/2)-(centerBox._width/2));
  32.     boxTween = new mx.transitions.Tween(centerBox, "_y", mx.transitions.easing.Back.easeOut, 0, Math.round((Stage.height/2)-(centerBox._height/2)), 40);
  33.     credits_txt._width = Stage.width;
  34.     credits_txt._y = (Stage.height)-credits_txt._height;
  35.     credits_txt.text = "Created by: New Ezra - Box _x:"+centerBox._x+", Box _y:"+centerBox._y;
  36. };
  37. //All non-IE browsers need this in order to set initial properties
  38. //IE automaticly calls back onResize when opened
  39. //**Possible bug - submitted to Macromedia
  40. stageResize();
  41. //Creates stageListener Object
  42. var stageListener:Object = new Object();
  43. //Defines function for stage onResize
  44. stageListener.onResize = function() {
  45.     stageResize();
  46. };
  47. //Adds the stageListener to call
  48. Stage.addListener(stageListener);
Reply With Quote  
theJhereg theJhereg is offline theJhereg lives in United States 2004-12-15 #10 Old  
AS 2 Class
With permission, though I'd post up an AS2 class that I use all the time does the same thing. Same code and method.

ActionScript Code:
  1. class CenteredMC extends MovieClip {
  2.     public var o_listener:Object ;
  3.     
  4.     public function CenteredMC() {
  5.         Stage.align = "TL" ;
  6.         Stage.scaleMode = "noScale" ;
  7.         
  8.         this.o_listener = new Object() ;
  9.         var owner = this ;
  10.         this.o_listener.onResize = function() {
  11.             owner.CenterMovieClip() ;
  12.         };
  13.     }
  14.  
  15.     public function onLoad() {
  16.         Stage.addListener(this.o_listener) ;
  17.         this.CenterMovieClip() ;
  18.     }
  19.     public function CenterMovieClip():Void {
  20.         this._x = Math.round((Stage.width/2)-(this._width/2));
  21.         this._y = Math.round((Stage.height/2)-(this._height/2));
  22.     }
  23. }

When I can generalize it a bit more to be useful for everyone, I've got another class that uses the same methodology to stretch a MC as a background, optionally with a margin, and options to maintain aspect ratio, indicate it's placement (top-center, top-left, etc).
Reply With Quote  
phlackee's Avatar phlackee phlackee is offline phlackee lives in Kosovo, Republic of 2004-12-15 #11 Old  
Great Blue.
its great tut. I had some problems like that, and maybe I got to use it. perfect
Reply With Quote  
sentinels sentinels is offline sentinels lives in United States 2004-12-15 #12 Old  
Re: [mini-tutorial] Center MovieClip on Stage
if you're going to use XHTML, this won't validate with the <embed> tags in there.

check here: http://www.alistapart.com/articles/flashsatay
Reply With Quote  
NewEzra's Avatar NewEzra NewEzra is offline NewEzra lives in United States 2004-12-15 #13 Old  
Re: Re: [mini-tutorial] Center MovieClip on Stage
Originally posted by sentinels
if you're going to use XHTML, this won't validate with the <embed> tags in there.

check here: http://www.alistapart.com/articles/flashsatay
You're right, but in all honesty if you're working with a 100% flash window fill there is no point in needing to validate. That would only apply if you're using flash with other xhtml content.
Reply With Quote  
sentinels sentinels is offline sentinels lives in United States 2004-12-15 #14 Old  
good point.
Reply With Quote  
feel feel is offline 2004-12-15 #15 Old  
theJhereg

how to use the CenteredMC class?
Reply With Quote  
theJhereg theJhereg is offline theJhereg lives in United States 2004-12-15 #16 Old  
Sorry feel, neglected to put that in.

Save the ActionScript above as "CenteredMC.as" and place it in your class path, or in the same folder as your FLA file.

Then, in the library, right click the movie clip you want to be centered, and select Linkage. Check the "export for actionscript" checkbox, and enter "CenteredMC" as the AS 2.0 Class.

Flash will take care of the rest.
Reply With Quote  
feel feel is offline 2004-12-15 #17 Old  
Neverrain

thanks for your code.
question?
how to when resize stage in second time. the box go back to the top and do easing, how can make it start from the current position?
Reply With Quote  
feel feel is offline 2004-12-15 #18 Old  
theJhereg,

it's ok.. i did figurage it out
just save the class use "CenteredMC.as"
then use i can call it by as
ActionScript Code:
  1. mc.CenteredMC()
Reply With Quote  
gobbadh gobbadh is offline 2004-12-16 #19 Old  
what do you think with this centerStage with easing here at http://vumedio.com
Reply With Quote  
gobbadh gobbadh is offline 2004-12-16 #20 Old  
try to resize your browser it will slides to center
Reply With Quote  
theJhereg theJhereg is offline theJhereg lives in United States 2004-12-16 #21 Old  
Okay, Refined te CenterMC class, and added another class for stretching a background MC, with a few parameters for different uses. I put that full example in another thread to keep from taking over this one.

[Example] Center/Background MovieClip


Refinement is just a bit of steamlining of the class (had a redundant listener)
ActionScript Code:
  1. class CenteredMC extends MovieClip {
  2.     public function CenteredMC() {
  3.         Stage.align = "TL" ;
  4.         Stage.scaleMode = "noScale" ;
  5.     }
  6.     public function onLoad() {
  7.         Stage.addListener(this) ;
  8.         this.onResize() ;
  9.     }
  10.     public function onResize():Void {
  11.         this._x = Math.round((Stage.width/2)-(this._width/2));
  12.         this._y = Math.round((Stage.height/2)-(this._height/2));
  13.     }
  14. }

The example in the other thread shows usage for both.

Thanks to bluebox_d for the mini-tutorial, and permission to extend in AS2.
Reply With Quote  
Too-Short Too-Short is offline 2004-12-23 #22 Old  
this is great BUT.

i dont have mx2004 do you have this for mx as welll?

many thanks
Reply With Quote  
Mounty's Avatar Mounty Mounty is offline Moderator Mounty lives in United Kingdom Creative Assets 2004-12-23 #23 Old  
Now with added scrollbars when needed!
Last edited by Mounty : 2004-12-23 at 07:11.
OK, can't be arsed to make this a class but here you go:

ActionScript Code:
  1. //Set stage to fill screen and align top left
  2. contentWidth = 700;
  3. contentHeight = 300;
  4. Stage.scaleMode = "noScale";
  5. Stage.align = "TL";
  6. //Function defines and sets based on initial Stage properties
  7. //fore._visible = false;
  8.  
  9. fore=this.createEmptyMovieClip("centerBox", this.getNextHighestDepth());
  10. centerBox.beginFill(0x000000);
  11. centerBox.moveTo(0, 0);
  12. centerBox.lineTo(contentWidth, 0);
  13. centerBox.lineTo(contentWidth, contentHeight);
  14. centerBox.lineTo(0, contentHeight);
  15. centerBox.lineTo(0, 0);
  16. centerBox.endFill();
  17. this.createEmptyMovieClip("viewPanel", this.getNextHighestDepth());
  18. viewPanel.beginFill(0x000000);
  19. viewPanel.moveTo(0, 0);
  20. viewPanel.lineTo(contentWidth, 0);
  21. viewPanel.lineTo(contentWidth, contentHeight);
  22. viewPanel.lineTo(0, contentHeight);
  23. viewPanel.lineTo(0, 0);
  24. viewPanel.endFill();
  25. //
  26. viewPanel._visible = false;
  27. content_mc.swapDepths(this.getNextHighestDepth());
  28. content_mc.setStyle("borderStyle", "none");
  29. content_mc.contentPath ="content.swf";
  30.  
  31. stageResize = function () {
  32.     centerBox._x = Math.round((Stage.width/2)-(centerBox._width/2));
  33.     centerBox._y = Math.round((Stage.height/2)-(centerBox._height/2));
  34.     back._width = Stage.width;
  35.     back._height = Stage.height;
  36.     back._x = 0;
  37.     back._y = 0;
  38.     if (centerBox._width>Stage.width && centerBox._height<Stage.height) {
  39.         content_mc._x = viewPanel._x=Math.round((Stage.width/2)-(viewPanel._width/2));
  40.         viewPanel._width = Stage.width;
  41.         content_mc.setSize(Stage.width, fore._height);
  42.         viewPanel._height = centerBox._height;
  43.         content_mc._y = viewPanel._y=centerBox._y;
  44.         trace("resizing horizontal");
  45.     } else if (centerBox._height>Stage.height && centerBox._width<Stage.width) {
  46.         content_mc._y = viewPanel._y=Math.round((Stage.height/2)-(viewPanel._height/2));
  47.         viewPanel._height = Stage.height;
  48.         content_mc.setSize(fore._width, Stage.height);
  49.         content_mc._x = viewPanel._x=centerBox._x;
  50.         viewPanel._width = centerBox._width;
  51.         trace("resizing verticle");
  52.     } else if (centerBox._height>Stage.height && centerBox._width>Stage.width) {
  53.         content_mc.setSize(Stage.width, Stage.height);
  54.         content_mc._x = viewPanel._y=Math.round((Stage.height/2)-(viewPanel._height/2));
  55.         content_mc._y = viewPanel._x=Math.round((Stage.width/2)-(viewPanel._width/2));
  56.         viewPanel._height = Stage.height;
  57.         viewPanel._width = Stage.width;
  58.     } else {
  59.         // reset
  60.         content_mc._x = viewPanel._x=centerBox._x;
  61.         viewPanel._width = centerBox._width;
  62.         viewPanel._height = centerBox._height;
  63.         content_mc._y = viewPanel._y=centerBox._y;
  64.         content_mc.setSize(centerBox._width, centerBox._height);
  65.     }
  66.     content_mc.redraw();
  67. };
  68. //All non-IE browsers need this in order to set initial properties
  69. //IE automaticly calls back onResize when opened
  70. //**Possible bug - submitted to Macromedia
  71. stageResize();
  72. //Creates stageListener Object
  73. var stageListener:Object = new Object();
  74. //Defines function for stage onResize
  75. stageListener.onResize = function() {
  76.     stageResize();
  77. };
  78. //Adds the stageListener to call
  79. Stage.addListener(stageListener);

So you'll need an mc on the stage called 'back' which'll always scale to fit the stage.

You'll also need a scrollpane instance called 'content_mc' on stage.

Plus you'll need a swf called "content.swf" with your content in.

Try resizing the stage, you should get scroll bars if the stage size drops below the content size, or if the content is already bigger than the scrollpane.

It could still be buggy, definately not optimised, but may just be useful - feel free to improve.

Merry Christmas

M

 Reply With Quote  
macronesia macronesia is offline 2004-12-23 #24 Old  
Re: Re: [mini-tutorial] Center MovieClip on Stage
Originally posted by sentinels
if you're going to use XHTML, this won't validate with the <embed> tags in there.

check here: http://www.alistapart.com/articles/flashsatay
that's a nasty workaround... make a blank swf that loads another swf? not practical. just call the entire flash file via JavaScript. almost everyone has JavaScript enabled.
Reply With Quote  
Decarn Decarn is offline 2004-12-29 #25 Old  
I've d/l the file but the lower potion of my background picture was cut off.

Any ideas?
Reply With Quote  
stormBliss stormBliss is offline 2005-01-05 #26 Old  
theJhereg, ive used your method, its ok for the swf and tks a lot!
but in the html it refuses to align ...
Reply With Quote  
theJhereg theJhereg is offline theJhereg lives in United States 2005-01-05 #27 Old  
stormBliss,

The HTML has to be set up pretty specifically so that there is no margin or padding in the body, and the flash object/embed fills 100% height & width of the page.

Keep in mind, if you don't set the publishing preferences NOT to publish HTML, flash will continually overwrite your custom HTML every time you publish.

Gimme just a few and I'll post up the HTML (blue_box's HTML has some errors and omissions for FireFox).
Reply With Quote  
theJhereg theJhereg is offline theJhereg lives in United States 2005-01-05 #28 Old  
HTML Code
Okay, here's the basic HTML to get your SWF to fill the page. Tweak to your own use (swf name, params, etc.) Of note:

1) The styles applied to html and body are important. Firefox only allows percent widths and heights if the container has a set width and height. Thus body's container is html.

2) The EMBED and the OBJECT tag BOTH have their height and width set to 100% and a style that also sets their height and width in CSS, and removes any margin. Older browsers ignore the style, and newer browsers can optionally ignore the height width, so I use both.

3) I normally don't use a transitional doctype, but I wasn't sure if I should push a strict doctype and web standards on ya ; )

Code:
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
<title>Untitled-1</title>
<style>
html { width:100%;height:100%;margin:0;padding:0 ;}
body { width:100%;height:100%;margin:0;padding:0 ;}
</style>
</head>
<body bgcolor="#000000">
<object classid="clsid:d27cdb6e-ae6d-11cf-96b8-444553540000" 
 codebase="http://fpdownload.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=7,0,0,0" 
 width="100%" 
 height="100%"
 style="width:100%;height:100%;margin:0;padding:0;"
 id="Untitled"
 align="middle">
   <param name="allowScriptAccess" value="sameDomain" />
   <param name="movie" value="Untitled-1.swf" />
   <param name="quality" value="high" />
   <param name="bgcolor" value="#000000" />
   <embed  src="Untitled-1.swf" 
     quality="high" 
     bgcolor="#000000" 
     width="100%" 
     height="100%" 
     style="width:100%;height:100%;margin:0;padding:0;"
     name="Untitled" 
     align="middle" 
     allowScriptAccess="sameDomain" 
     type="application/x-shockwave-flash"
     pluginspage="http://www.macromedia.com/go/getflashplayer" />
</object>
</body>
</html>
 Reply With Quote  
stormBliss stormBliss is offline 2005-01-05 #29 Old  
10x a lot!
Reply With Quote  
Syngenius Syngenius is offline 2005-01-05 #30 Old  
great tutorial..i was wondering how people do this
Reply With Quote  
NewEzra's Avatar NewEzra NewEzra is offline NewEzra lives in United States 2005-02-16 #31 Old  
Re: HTML Code
Originally posted by theJhereg
Okay, here's the basic HTML to get your SWF to fill the page. Tweak to your own use (swf name, params, etc.) Of note:
Call me crazy, but why in the world would you care if it validates or not... you're using a full window of flash, there's nothing to validate.
Reply With Quote  
theJhereg theJhereg is offline theJhereg lives in United States 2005-02-16 #32 Old  
Ugh, you're gonna make me remember what the hell I was talking about a month ago? I've slept since then

I'll guess that you're talking about the strict/transitional doctype right? If so the point of a doctype isn't just about validation. It tells the browser what type of content to expect, and how to interpret it.

I use strict doctype almost exclusively because it forces IE into a "standards mode" where the box model most resembles firefox/gecko.

Is it strictly mandatory, naaa. It's just good practice to use a doctype, and its just the way I do things.

If I'm answering the wrong question, feel free to point out what I'm missing.
Reply With Quote  
ewinter ewinter is offline ewinter lives in Croatia 2005-02-17 #33 Old  
Align Components:


http://chq.emehmedovic.com/?id=7

I use them everywhere, for every kind of resizability; not only for aligning to Stage, but to implement resizable pane/button/scrollbar/window components, etc.
Reply With Quote  
rcarroll rcarroll is offline rcarroll lives in United Kingdom 2005-02-17 #34 Old  
WOW...

It is downloaded - great tut - been wanting to do that for a while now.

Cheers
Reply With Quote  
tb1200 tb1200 is offline 2005-04-11 #35 Old  
<edited> scratch that... works great now!
Reply With Quote  
possum4all possum4all is offline 2005-05-17 #36 Old  
What about a tiled background?
Reply With Quote  
t3x's Avatar t3x t3x is offline t3x lives in Australia 2005-08-16 #37 Old  
Hello all, i need a little help with this movie. i made an MC in that movie that i put on the stage. Now what kind of actionscripts do i have to put on that MC for it to reposition itself on the right of the screen for example, whenever i resize the window.

i hope you all understand what i meen.
Reply With Quote  
Codemonkey's Avatar Codemonkey Codemonkey is offline Super Moderator Codemonkey lives in Netherlands 2005-08-16 #38 Old  
Originally posted by stormBliss
10x a lot!
Reply With Quote  
t3x's Avatar t3x t3x is offline t3x lives in Australia 2005-08-16 #39 Old  
don't worry about what i posted, i figured it out myself
Reply With Quote  
Goten's Avatar Goten Goten is offline Goten lives in Mexico Creative Assets 2005-08-22 #40 Old  
thnks Jo... very usefull
Reply With Quote  
1|2|> Page 1 of 2
Thread Tools
Display Modes Rate This Thread
Linear Mode Linear Mode
Rate This Thread: