hi everybody.


I'm very new to class'es, and still bumping into crazy errors.
in my recent project, I get this error over and over again:
TypeError: Error #2007: Parameter sound must be non-null.

my project is a class, that not only plays a .mp3, but visualizes it at the same time.
to do this, I've written this in my .fla:

stop();

//set up the VisualizeMusic class
import VisualizeMusic;
var visualizemusic:VisualizeMusic = new VisualizeMusic();
addChild(visualizemusic);
// now the stage property of the class is no longer null

//music, number of times to loop
visualizemusic.init("vibe_music.mp3", 9999);

and the following in my .as-file:

package {

	import flash.display.Sprite;
	import flash.media.Sound;
	import flash.media.SoundMixer;
	import flash.net.URLRequest;
	import flash.utils.ByteArray;
	import flash.events.Event;
	//import flash.text.TextField;
	
	public class VisualizeMusic extends Sprite {
		
		private var theMusic:String;
		private var numberOfLoops:Number;
		private var bytearray:ByteArray;
		
		public function VisualizeMusic() {
			trace("function VisualizeMusic");
		}
		
		public function init(music:String, numLoops:Number):void {
			theMusic = music;
			numberOfLoops = numLoops
			trace("VisualizeMusic initiated");
			var bytearray:ByteArray = new ByteArray();
			var mysound:Sound = new Sound(new URLRequest(theMusic));
			addEventListener(Event.ENTER_FRAME, doTheGraphics);
			mysound.play(0, numberOfLoops);
			
		}
		
		private function doTheGraphics(event:Event):void{
			trace("function doTheGraphics");
			var myVisualizer:Sprite = new Sprite();
			myVisualizer.graphics.clear;
			myVisualizer.graphics.lineStyle(1, 0xFFFFFF);
			myVisualizer.graphics.moveTo(0, 50);
			SoundMixer.computeSpectrum(bytearray);
			for(var i:uint = 0; i<256; i++){
				//the readFloat reads the next value in the ByteArray and assigns it to a Number
				var num:Number = bytearray.readFloat()*40 + 50;
				myVisualizer.graphics.lineTo(i*.4, num);
			}
		}
	}
}

it seems kinda straightahead to me.
the init function sets up the sound and plays it, and the eventListener fires the doTheGraphics-function.
but somethings is not done correctly, I just can't figure out what...


can anyone help me?
thanks
felisan

---------------------------------------------
http://www.campjohn.dk/wp/

[Rackdoll]

i think if you dont push the URLRequest right away in the SOund it should be fine.
Just make a soundObject and do not pass a URLRequest in it...
Then just play or load the URLRequest..

[felisan]

hi Rackdoll.

I'm not sure what you mean...
I've tried this:

var mysound:Sound = new Sound;
mysound(new URLRequest(theMusic));

but that doesn't help.
what did you mean?


thanks
felisan

[felisan]

please, can anyone help?

[-Loren-]

Hi!,

I made a few modifications to your code, but everything is working now

Here is the new code, I will explain some of my changes below:

package {
 
    import flash.display.Sprite;
    import flash.media.Sound;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    import flash.events.Event;
    //import flash.text.TextField;
    
    public class VisualizeMusic extends Sprite {
        
        private var theMusic:String;
        private var numberOfLoops:Number;
        private var bytearray:ByteArray = new ByteArray();
        private var mysound:Sound = new Sound(); 
        private var myVisualizer:Sprite = new Sprite();
        public function VisualizeMusic() {
            trace("function VisualizeMusic");
        }
        
        public function init(music:String, numLoops:Number):void {
            this.addChild(myVisualizer);
            theMusic = music;
            numberOfLoops = numLoops
            trace("VisualizeMusic initiated");
            var bytearray:ByteArray = new ByteArray();
            mysound.load(new URLRequest(theMusic));
            addEventListener(Event.ENTER_FRAME, doTheGraphics);
            mysound.play(0, numberOfLoops);
            
        }
        
        private function doTheGraphics(event:Event):void{
            
            trace("function doTheGraphics");
            myVisualizer.graphics.clear();
            myVisualizer.graphics.lineStyle(1, 0xFFFFFF);
            myVisualizer.graphics.moveTo(0, 50);
            
            SoundMixer.computeSpectrum(bytearray,true,0);
            for(var i:uint = 0; i<256; i++){
                //the readFloat reads the next value in the ByteArray and assigns it to a Number
                var num:Number = bytearray.readFloat()*40 + 50;
                myVisualizer.graphics.lineTo(i*.4, num);
            }
            
        }
    }
} 

First thing I did was finish the constructor for ByteArray. Byte arrays need to be instantiated like a standard array, like this: var byteArray:ByteArray = new ByteArray(); (You had everything except the = new ByteArray() part).

I added your display sprite's declaration with your other private variables so it would only need to be referenced once throughout the visualizations. I also added this.addChild(myVisualizer); to your init, so that the content being drawn within that sprite would be visible to the user.

I moved your Sound constructor with your other private variables, again, to make it a global reference.

I completed your clear function inside your doTheGraphics function. You just didn't have parenthesis after clear, as in clear();

I removed the new constructor from your myVisualizer sprite since in this case, reinstantiating myVisualizer would cause your system to get very bogged down with that many sprites being referenced in the application.

I hope this helps, let me know if anything else arises.

[felisan]

ok.
- you corrected ByteArray and clear.
- you added the displaySprite to the displaylist, making it visible.
- then you listed Sound and displaySprite among the other private variables for quicker future reference.
- and finally you removed the instantiation of the displaySprite for better flow.

correct?

thanks.
you have helped me very much owe you one!
felisan

[-Loren-]

Yep, I believe that was it Have fun, visualizations are a great thing to learn with.

[babbje]

I need help. I have this action script here...and I keep getting that same error

TypeError: Error #2007: Parameter child must be non-null.
at flash.display:isplayObjectContainer/removeChild()
at DotDrawFull_startTryone_fla::MainTimeline/clearCanvas()

This is my action script. I believe the only thing wrong with it is at the bottom which states:
clear_btn.addEventListener(MouseEvent.CLICK, clearCanvas);

function clearCanvas (evt:MouseEvent): void {
var myDot_mc: MovieClip;
var numbDots:Number=dotArray.length;
for (var i:Number= 0; i<numbDots; i++)
myDot_mc=dotArray.pop();
canvas.removeChild(myDot_mc);
myDot_mc=null;
}

When I have this action script I should be able to press this button with a instance name clear_btn and the dots on the page should be "erased". I don't know what is going on. Here is the full action script

var currentColor:String= "green";
var dotArray:Array= new Array;

setGreen_btn.addEventListener (MouseEvent.CLICK,setGreenPencil);
setRed_btn.addEventListener (MouseEvent.CLICK, setRedPencil);
setBlue_btn.addEventListener (MouseEvent.CLICK, setBluePencil);

function setGreenPencil(evt:MouseEvent): void {
currentColor= "green";
}

function setRedPencil (evt:MouseEvent): void {
currentColor="red";
}

function setBluePencil(evt:MouseEvent): void {
currentColor="blue";
}

canvas.addEventListener (MouseEvent.MOUSE_DOWN, startDraw);

function startDraw (evt:MouseEvent): void{
canvas.addEventListener(MouseEvent.MOUSE_MOVE, drawShape);
canvas.addEventListener(MouseEvent.MOUSE_UP, stopDraw);
}

function drawShape (evt:MouseEvent): void{
var myDot_mc: MovieClip;
if (currentColor == "red") {
myDot_mc=new RedDot ();
} else if (currentColor == "blue") {
myDot_mc=new BlueDot();
} else {
myDot_mc=new GreenDot ();
}
myDot_mc.x=mouseX-canvas.x;
myDot_mc.y=mouseY-canvas.y;
dotArray.push (myDot_mc);
canvas.addChild(myDot_mc);
}

function stopDraw (evt:MouseEvent):void {
canvas.removeEventListener(MouseEvent.MOUSE_MOVE,drawShape);
canvas.removeEventListener(MouseEvent.MOUSE_UP, stopDraw);
}

clear_btn.addEventListener(MouseEvent.CLICK, clearCanvas);

function clearCanvas (evt:MouseEvent): void {
var myDot_mc: MovieClip;
var numbDots:Number=dotArray.length;
for (var i:Number= 0; i<numbDots; i++)
myDot_mc=dotArray.pop();
canvas.removeChild(myDot_mc);
myDot_mc=null;
}