I making the transition to AS3 and am having trouble figuring this out. I have a animated movieclip (circle_mc) and the last frame is labeled "cover". How do I trigger a function when the frame with the label is reached?

This isn't working

circle_mc.addEventListener(Event.ENTER_FRAME, cover, false,0,true); 

[Isocase]

If I can remember correctly you cannot target a frame specifically by calling the frame label. I would just make a custom event class and then dispatch an even when you hit whatever frame/label you want. Here is an example, I made a quick custom event class and in the FLA but code on frame 1 and frame 30.

Code on frame 1:

import AnimationEvent;

addEventListener( AnimationEvent.FOO, foo, false, 0, true );

function foo( e:AnimationEvent ):void
{
	trace( "This method runs when the timeline hits frame 30" );
}

Code on frame 30:

stop();

dispatchEvent( new AnimationEvent( AnimationEvent.FOO ) );

Custom event class:

package
{
	import flash.events.Event;
	
	public class AnimationEvent extends Event
	{
		public static const FOO:String = "foo";
		
		public function AnimationEvent( type:String )
		{
			super( type );
		}
		
		override public function clone():Event
		{
			return new AnimationEvent( type );
		}
		
		override public function toString():String
		{
			return formatToString( "AnimationEvent", "bubbles", "cancelable", "eventPhase" );
		}
	}
}

[co2]

Thanks for your help Isocase. Would an EventListener on the labeled frame work also?

[Isocase]

You can add the event listener anywhere you want. You just have to make sure you dispatch the event so there is something to listen for.

[co2]

Thanks again for your help. I was able to get it to work with this code on the main timeline.

circle_mc.addEventListener(Event.ENTER_FRAME, checkFrame);
 
function checkFrame(evt:Event):void {
   if (circle_mc.currentLabel == "cover") {
      circle_mc.removeEventListener(Event.ENTER_FRAME, checkFrame);
      TweenMax.to(cover_mc, 2, { scaleX:.2, scaleY:.2, ease:Cubic.easeIn});
   }
} 

Wohoo! 100th post!!!