[Nutrox]

 
Using the bit-shifting techniques that Codemonkey has covered allows you to quickly and easily manipulate colour values.

This first example demostrates how you can get the individual colour values from a RGB colour value:

var colour:Number = 0xFA802A;
 
var red:Number   = colour >> 16 & 255;
var green:Number = colour >> 8 & 255;
var blue:Number  = colour & 255;
 
trace( red   ); // 250
trace( green ); // 128
trace( blue  ); // 42
 
trace( red.toString(16)   ); // fa
trace( green.toString(16) ); // 80
trace( blue.toString(16)  ); // 2a 
 

If you want to construct a RGB colour value from red, green, and blue values then you can do this:

var red:Number   = 0x80;
var green:Number = 0xFF;
var blue:Number  = 0xCA;
 
var colour:Number = 0;
 
colour |= red   << 16;
colour |= green << 8;
colour |= blue;
 
trace( colour );              // 16711882
trace( colour.toString(16) ); // 80ffca 
 

A quicker/cleaner way:

colour = (red << 16) | (green << 8) | blue; 

The following functions will allow you to adjust the red, green, or blue colour value in a colour:

function setRed( colour:Number, value:Number ):Number
{
    colour = ( colour & 0x00FFFF ) | ( value << 16 );
    return colour;
}
 
function setGreen( colour:Number, value:Number ):Number
{
    colour = ( colour & 0xFF00FF ) | ( value << 8 );
    return colour;
}
 
function setBlue( colour:Number, value:Number ):Number
{
    colour = ( colour & 0xFFFF00 ) | value;
    return colour;
}
 
//
 
var colour:Number = 0x00FF00;
 
// Add some red to the colour.
colour = setRed( colour, 0xDA );
 
// Add some blue to the colour.
colour = setBlue( colour, 0x44 );
 
trace( colour.toString(16) ); // daff44