[Nutrox]

Hi Guys.


Here's an example of how to create a tiled bitmap in Flash (as requested by MYTiX).

Here's the important part...

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;
 
function createTiles(target:BitmapData, tileID:String):Void {
    var tile_bmp:BitmapData = BitmapData.loadBitmap(tileID);
    var tW:Number = tile_bmp.rectangle.width;
    var tH:Number = tile_bmp.rectangle.height;
    var tX:Number = Math.ceil(target.rectangle.width / tW);
    var tY:Number = Math.ceil(target.rectangle.height /  tH);
    for(var x:Number = 0; x < tX; x++) {
        for(var y:Number = 0; y < tY; y++) {
            var rect:Rectangle = new Rectangle(0,0,tW,tH);
            var point:Point = new Point(tW*x,tH*y);
            target.copyPixels(tile_bmp, rect, point);
        }
    }
}; 

...and this is an example of how to use it...

// CREATE AN EMPTY MOVIECLIP TO USE AS A CONTAINER
var container_mc:MovieClip = this.createEmptyMovieClip("container_mc", 0);
 
// CREATE A NEW BITMAP
var target_bmp:BitmapData = new BitmapData(600, 300, false, 0);
 
// ATTACH THE BITMAP TO THE CONTAINER
container_mc.attachBitmap(target_bmp,0);
 
// CALL THE createTiles FUNCTION SO THAT THE CONTAINER BITMAP
// IS TILED WITH A PNG (etc) FROM THE LIBRARY
createTiles(target_bmp, "source3BMP"); 

source3BMP is the linkage name I gave a PNG in the library when I was testing the function, this can obviously be changed to whatever you want.

Hope that's of some use.